Z Yapı Mühendisi

Autocad de tıkladığın herhangi iki nokta arasındaki uzaklığı yazar.

AutoCAD iki nokta arasındaki uzunluğu yazan lisp

Autocad lisp kodlar

Lisp dosyasını oluşturmayı ve AutoCAD"e yüklemeyi bilmiyorsanız. Lispi bilgisayara kaydetmek ve AutoCAD"e yüklemek için AutoCAD lisp dosyasını kaydetme ve yükleme nasıl yapılır yazısını okuyun

AutoCAD iki nokta arasındaki uzunluğu yazan lisp resimli anlatım

- Komut satırına "UZUNLUK-IKI-NOKTA" yazın ve enter tuşuna basın

- yazi boyu istenecek, yazılacak yazının yüksekliğini belirleyin. 10 20 100 şeklinde bir sayı giriniz

- ben yazı boyunu 4 yazıp entera basıyorum

- ilk noktayı giriniz : ilk noktaya ekranda tıklayınız

- ikinci noktaya ekranda tıklayınız

- ikinci noktaya tıkladıktan sonra arasındaki mesafeyi üzerine yazar

AutoCAD iki nokta arasındaki uzunluğu yazan lisp daha fazla ara

👀 google

👀 yandex

👀 bing

👀 youtube

👀 facebook

👀 wikipedia

👀 google kitap

👀 google trends

👀 uzmantv

👀 twitter

👀 pinterest

👀 eksisozluk

AutoCAD iki nokta arasındaki uzunluğu yazan lisp ilgili benzer konular

👀 autocad uzunluk ölçme komutu

👀 autocad seçilen çizgilerin toplam uzunluğu

👀 autocad çizgi uzunluğu gösterme

👀 autocad kot verme

👀 autocad spline uzunluğu ölçme kısayol

👀 autocad uzunluk yazma

👀 harocad lisp

AutoCAD iki nokta arasındaki uzunluğu yazan lisp - Metraj Lispi

Hiç yorum yok:
3 Mart 2021 Çarşamba

🐄 Metraj Lispi 🐊 uzunluk lispleri lisp

Bir kaç çizginin uzunluklarını toplayarak toplam uzunluğunu verir.

Autocad lisp kodlar

(defun c:UZUNLUK-METRAJ ()
  (setvar "modemacro" "zyapimuhendisi.blogspot.com")
  (vl-load-com)
  (setq secim (ssget '((-4 . "<OR")
       (0 . "LINE")
       (0 . "LWPOLYLINE")
       (0 . "ARC")
       (0 . "ELLIPSE")
       (0 . "SPLINE")
       (0 . "CIRCLE")
       (-4 . "OR>")
      )
      )
  )
  (if (= secim nil)
    (progn
    )
    (progn
      (setq sayim (sslength secim))
      (setq toplami 0
    c 0
      )
      (while (< c sayim)
(setq teksecim (ssname secim c))
(setq tanimi (cdr (assoc 0 (entget teksecim))))
(if (= tanimi "ARC")
  (progn
    (setq data (vlax-ename->vla-object teksecim))
    (setq uz-bul (vla-get-arclength data))
    (setq toplami (+ toplami uz-bul))
  ))
(if (or (= tanimi "LINE")(= tanimi "LWPOLYLINE")(= tanimi "POLYLINE"))
  (progn
    (setq data (vlax-ename->vla-object teksecim))
    (setq uz-bul (vla-get-length data))
    (setq toplami (+ toplami uz-bul))
  )
)
(if (= tanimi "CIRCLE")
  (progn
    (setq data (vlax-ename->vla-object teksecim))
    (setq uz-bul (vla-get-circumference data))
    (setq toplami (+ toplami uz-bul))))
(if (or (= tanimi "ELLIPSE")(= tanimi "SPLINE"))
  (progn
    (command "._area" "e" teksecim)
    (setq uz-bul (getvar "perimeter"))
    (setq toplami (+ toplami uz-bul))))
(setq c (+ c 1))
      )
      (alert (strcat "\nToplam Uzunluk : " (rtos toplami 2 3)))
    )
  )
  (princ)
)

Autocad lisp çalıştırma

Kumanda satırına UZUNLUK-METRAJ yazın ve enter tuşuna basın
Metrajını almak istediğiniz çizgilere ekranda tıklayın veya toplu seçin
Line ve polyline hepsini seçiyorum
Enter tuşuna basın.
Kaç şekil seçildiği kumanda satırında yazar
Toplam uzunluk açılan pencerede yazar

AutoCAD çizgileri toplayan lips - Metraj Lispi

Hiç yorum yok:
2 Mart 2021 Salı

🐄 Metraj Lispi 🐊 uzunluk lispleri lisp

🍅 Alanlarını bulmak istediğiniz bir veya bir kaç nesneye tıkladığınızda, Toplam alanları komut satırında gösteren lisp.

Autocad lisp kodlar

(defun c:ALAN-SATIRDA-GOSTER (/ olderr oldcmdecho errexit undox restore ss1 nr en tot_area)
  (defun errexit (s)
    (restore)
  )

(defun undox ()
    (command "._undo" "_E")
    (setvar "cmdecho" oldcmdecho)
    (setq *error* olderr)
    (princ)
  )

(setq olderr  *error*
        restore undox
        *error* errexit
  )
  (setq oldcmdecho (getvar "cmdecho"))
  (setvar "cmdecho" 0)
  (command "._UNDO" "_BE")
  (if (setq ss1 (ssget '((-4 . "<OR")
                         (0 . "POLYLINE")
                         (0 . "LWPOLYLINE")
                         (0 . "CIRCLE")
                         (0 . "ELLIPSE")
                         (0 . "SPLINE")
                         (0 . "REGION")
                         (-4 . "OR>")
                        )
                )
      )
    (progn
      (setq nr 0)
      (setq tot_area 0.0)
      (setq en (ssname ss1 nr))
      (while en
        (command "._area" "_O" en)
        (setq tot_area (+ tot_area (getvar "area")))
        (setq nr (1+ nr))
        (setq en (ssname ss1 nr))
      )
      (princ "\nTotal Area = ")
      (princ tot_area)
    )
  )
  (setq ss1 nil)
  (restore)
)

Autocad lisp çalıştırma

📜 Komut satırına "ALAN-TOPLAM" yazın ve enterlayın

📜Select object : Toplam alanı bulmak istediğiniz şekle tıklayın
Kareye tıklıyorum

📜Enter tuşuna basıyorum. Total area = 10000 birim kare

📜Şimdi başka bir şeklin alanı görelim.
ALAN-TOPLAM yazdım ve enter tuşuna bastım
İkin şekli şeçiyorum

📜Enter tuşuna basıyorum.
Select objects: 1 found
Select objects:
Total Area = 6759.27
2. şeklin alanı 6759,27 birim kare

📜Şimdi birden çok şeklin toplam alanını bulualım

kumanda satırına ALAN-TOPLAM yazıyorum
enter tuşuna basıyorum
alanını bulmak istediğim şekilleri (birkaçtane şekil seçiyorum)
Şekildeki 3 şekli seciyorum

📜enter tuşuna basıyorum
toplam alanına kumanda satırından bakıyorum.

AutoCAD toplam alanları satırda gösteren lisp daha fazla ara

👀 google

👀 yandex

👀 bing

👀 youtube

👀 facebook

👀 wikipedia

👀 google kitap

👀 google trends

👀 uzmantv

👀 twitter

👀 pinterest

👀 eksisozluk

AutoCAD toplam alanları satırda gösteren lisp ilgili benzer konular

👀 AutoCAD çizgileri toplayan lisp

👀 AutoCAD polyline uzunluk ölçme

👀 AutoCAD metraj komutu

👀 AutoCAD metraj lisp

AutoCAD toplam alanları satırda gösteren lisp - Metraj Lispi

Hiç yorum yok:

🐄 Metraj Lispi 🐅 Alan-Çevre Lispleri lisp

👱 Çizimde bulunan birden fazla alan için, Her bir alanı numaralandırır ve alan tablosu oluşturur.

alanları numaralandırıp tabloya aktaran lisp

Autocad lisp kodlar

(defun c:ALAN-TABLO nil (AreaLabel   t))  ;; Areas to Table
(defun c:ALAN-DOSYA nil (AreaLabel nil))  ;; Areas to File

(defun AreaLabel ( flag / *error* _startundo _endundo _centroid _text _open _select _getobjectid _isannotative
                          acdoc acspc ap ar as cf cm el fd fl fo n of om p1 pf pt sf st t1 t2 tb th ts tx ucsxang ucszdir )

(setq h1 "Alan Tablosu"  ;; Heading
        t1 "No"      ;; Number Title
        t2 "Alan"        ;; Area Title
        pf ""            ;; Number Prefix (optional, "" if none)
        sf ""            ;; Number Suffix (optional, "" if none)
        ap ""            ;; Area Prefix (optional, "" if none)
        as ""            ;; Area Suffix (optional, "" if none)
        cf 1.0           ;; Area Conversion Factor (e.g. 1e-6 = mm2->m2)
        fd t             ;; Use fields to link numbers/objects to table (t=yes, nil=no)
        fo "%lu6%qf1"    ;; Area field formatting
  )

;;------------------------------------------------------------;;

(defun *error* ( msg )
    (if cm (setvar 'CMDECHO cm))
    (if el (progn (entdel el) (setq el nil)))
    (if acdoc (_EndUndo acdoc))
    (if (and of (eq 'FILE (type of))) (close of))
    (if (and Shell (not (vlax-object-released-p Shell))) (vlax-release-object Shell))
    (if (null (wcmatch (strcase msg) "*BREAK,*CANCEL*,*EXIT*"))
        (princ (strcat "\n--> Error: " msg))
    )
    (princ)
  )

;;------------------------------------------------------------;;

(defun _StartUndo ( doc ) (_EndUndo doc)
    (vla-StartUndoMark doc)
  )

;;------------------------------------------------------------;;

(defun _EndUndo ( doc )
    (if (= 8 (logand 8 (getvar 'UNDOCTL)))
      (vla-EndUndoMark doc)
    )
  )

;;------------------------------------------------------------;;

(defun _centroid ( space objs / reg cen )
    (setq reg (car (vlax-invoke space 'addregion objs))
          cen (vlax-get reg 'centroid)
    )
    (vla-delete reg) (trans cen 1 0)
  )

;;------------------------------------------------------------;;

(defun _text ( space point string height rotation / text )
    (setq text (vla-addtext space string (vlax-3D-point point) height))
    (vla-put-alignment text acalignmentmiddlecenter)
    (vla-put-textalignmentpoint text (vlax-3D-point point))
    (vla-put-rotation text rotation)
    text
  )

;;------------------------------------------------------------;;

(defun _Open ( target / Shell result )
    (if (setq Shell (vla-getInterfaceObject (vlax-get-acad-object) "Shell.Application"))
      (progn
        (setq result
          (and (or (eq 'INT (type target)) (setq target (findfile target)))
            (not
              (vl-catch-all-error-p
                (vl-catch-all-apply 'vlax-invoke (list Shell 'Open target))
              )
            )
          )
        )
        (vlax-release-object Shell)
      )
    )
    result
  )

;;------------------------------------------------------------;;

(defun _Select ( msg pred func init / e ) (setq pred (eval pred)) 
    (while
      (progn (setvar 'ERRNO 0) (apply 'initget init) (setq e (func msg))
        (cond
          ( (= 7 (getvar 'ERRNO))
            (princ "\nMissed, try again.")
          )
          ( (eq 'STR (type e))
            nil
          )            
          ( (vl-consp e)
            (if (and pred (not (pred (setq e (car e)))))
              (princ "\nInvalid Object Selected.")
            )
          )
        )
      )
    )
    e
  )

;;------------------------------------------------------------;;

(defun _GetObjectID ( doc obj )
    (if (vl-string-search "64" (getenv "PROCESSOR_ARCHITECTURE"))
      (vlax-invoke-method (vla-get-Utility doc) 'GetObjectIdString obj :vlax-false)
      (itoa (vla-get-Objectid obj))
    )
  )

;;------------------------------------------------------------;;

(defun _isAnnotative ( style / object annotx )
    (and
      (setq object (tblobjname "STYLE" style))
      (setq annotx (cadr (assoc -3 (entget object '("AcadAnnotative")))))
      (= 1 (cdr (assoc 1070 (reverse annotx))))
    )
  )
  
  ;;------------------------------------------------------------;;

(setq acdoc (vla-get-activedocument (vlax-get-acad-object))
        acspc (vlax-get-property acdoc (if (= 1 (getvar 'CVPORT)) 'Paperspace 'Modelspace))

ucszdir (trans '(0. 0. 1.) 1 0 t)
        ucsxang (angle '(0. 0. 0.) (trans (getvar 'UCSXDIR) 0 ucszdir))
  )
  (_StartUndo acdoc)
  (setq cm (getvar 'CMDECHO))
  (setvar 'CMDECHO 0)
  (setq om (eq "1" (cond ((getenv "LMAC_AreaLabel")) ((setenv "LMAC_AreaLabel" "0")))))

(setq ts
    (/ (getvar 'TEXTSIZE)
      (if (_isAnnotative (getvar 'TEXTSTYLE))
        (cond ( (getvar 'CANNOSCALEVALUE) ) ( 1.0 )) 1.0
      )
    )
  )

(cond
    ( (not (vlax-method-applicable-p acspc 'addtable))

(princ "\n--> Table Objects not Available in this Version.")
    )
    ( (= 4 (logand 4 (cdr (assoc 70 (tblsearch "LAYER" (getvar 'CLAYER))))))

(princ "\n--> Current Layer Locked.")
    )
    ( (not
        (setq *al:num
          (cond
            (
              (getint
                (strcat "\nSpecify Starting Number <"
                  (itoa (setq *al:num (1+ (cond ( *al:num ) ( 0 ))))) ">: "
                )
              )
            )
            ( *al:num )
          )
        )
      )
    )
    ( flag

(setq th
        (* 2.
          (if
            (zerop
              (setq th
                (vla-gettextheight
                  (setq st
                    (vla-item
                      (vla-item
                        (vla-get-dictionaries acdoc) "ACAD_TABLESTYLE"
                      )
                      (getvar 'CTABLESTYLE)
                    )
                  )
                  acdatarow
                )
              )
            )
            ts
            (/ th
              (if (_isAnnotative (vla-gettextstyle st acdatarow))
                (cond ( (getvar 'CANNOSCALEVALUE) ) ( 1.0 )) 1.0
              )
            )
          )
        )
      )

(if
        (cond
          (
            (progn (initget "Add")
              (vl-consp (setq pt (getpoint "\nPick Point for Table <Add to Existing>: ")))
            )
            (setq tb
              (vla-addtable acspc
                (vlax-3D-point (trans pt 1 0)) 2 2 th (* 0.8 th (max (strlen t1) (strlen t2)))
              )
            )
            (vla-put-direction tb (vlax-3D-point (getvar 'UCSXDIR)))
            (vla-settext tb 0 0 h1)
            (vla-settext tb 1 0 t1)
            (vla-settext tb 1 1 t2)
            
            (while
              (progn
                (if om
                  (setq p1
                    (_Select (strcat "\nSelect Object [Pick] <Exit>: ")
                     '(lambda ( x )
                        (and
                          (vlax-property-available-p (vlax-ename->vla-object x) 'area)
                          (not (eq "HATCH" (cdr (assoc 0 (entget x)))))
                          (or (eq "REGION" (cdr (assoc 0 (entget x)))) (vlax-curve-isclosed x))
                        )
                      )
                      entsel '("Pick")
                    )
                  )
                  (progn (initget "Object") (setq p1 (getpoint "\nPick Area [Object] <Exit>: ")))
                )
                (cond
                  ( (null p1)

(vla-delete tb)
                  )
                  ( (eq "Pick" p1)

(setq om nil) t
                  )
                  ( (eq "Object" p1)

(setq om t)
                  )
                  ( (eq 'ENAME (type p1))

(setq tx
                      (cons
                        (_text acspc
                          (_centroid acspc (list (setq p1 (vlax-ename->vla-object p1))))
                          (strcat pf (itoa *al:num) sf)
                          ts
                          ucsxang
                        )
                        tx
                      )
                    )
                    (vla-insertrows tb (setq n 2) th 1)
                    (vla-settext tb n 1
                      (if fd
                        (strcat "%<\\AcObjProp Object(%<\\_ObjId "
                          (_GetObjectID acdoc p1) ">%).Area \\f \"" fo "\">%"
                        )
                        (strcat ap (rtos (* cf (vla-get-area p1)) 2) as)
                      )
                    )
                    (vla-settext tb n 0
                      (if fd
                        (strcat "%<\\AcObjProp Object(%<\\_ObjId "
                          (_GetObjectID acdoc (car tx)) ">%).TextString>%"
                        )
                        (strcat pf (itoa *al:num) sf)
                      )
                    )
                    nil
                  )                      
                  ( (vl-consp p1)

(setq el (entlast))
                    (vl-cmdf "_.-boundary" "_A" "_I" "_N" "" "_O" "_P" "" "_non" p1 "")

(if (not (equal el (setq el (entlast))))
                      (progn
                        (setq tx
                          (cons
                            (_text acspc
                              (_centroid acspc (list (vlax-ename->vla-object el)))
                              (strcat pf (itoa *al:num) sf)
                              ts
                              ucsxang
                            )
                            tx
                          )
                        )
                        (vla-insertrows tb (setq n 2) th 1)
                        (vla-settext tb n 1 (strcat ap (rtos (* cf (vlax-curve-getarea el)) 2) as))
                        (vla-settext tb n 0
                          (if fd
                            (strcat "%<\\AcObjProp Object(%<\\_ObjId "
                              (_GetObjectID acdoc (car tx)) ">%).TextString>%"
                            )
                            (strcat pf (itoa *al:num) sf)
                          )
                        )
                        (redraw el 3)
                        nil
                      )
                      (vla-delete tb)
                    )
                  )
                )
              )
            )
            (not (vlax-erased-p tb))
          )
          (
            (and
              (setq tb
                (_Select "\nSelect Table to Add to: "
                 '(lambda ( x ) (eq "ACAD_TABLE" (cdr (assoc 0 (entget x))))) entsel nil
                )
              )
              (< 1 (vla-get-columns (setq tb (vlax-ename->vla-object tb))))
            )
            (setq n (1- (vla-get-rows tb)) *al:num (1- *al:num))
          )
        )
        (progn
          (while
            (if om
              (setq p1
                (_Select (strcat "\nSelect Object [" (if tx "Undo/" "") "Pick] <Exit>: ")
                 '(lambda ( x )
                    (and
                      (vlax-property-available-p (vlax-ename->vla-object x) 'area)
                      (not (eq "HATCH" (cdr (assoc 0 (entget x)))))
                      (or (eq "REGION" (cdr (assoc 0 (entget x)))) (vlax-curve-isclosed x))
                    )
                  )
                  entsel (list (if tx "Undo Pick" "Pick"))
                )
              )
              (progn (initget (if tx "Undo Object" "Object"))
                (setq p1 (getpoint (strcat "\nPick Area [" (if tx "Undo/" "") "Object] <Exit>: ")))
              )
            )
            (cond
              ( (and tx (eq "Undo" p1))

(if el (progn (entdel el) (setq el nil)))
                (vla-deleterows tb n 1)
                (vla-delete (car tx))
                (setq n (1- n) tx (cdr tx) *al:num (1- *al:num))
              )
              ( (eq "Undo" p1)

(princ "\n--> Nothing to Undo.")
              )
              ( (eq "Object" p1)

(if el (progn (entdel el) (setq el nil)))
                (setq om t)
              )
              ( (eq "Pick" p1)

(setq om nil)
              )
              ( (and om (eq 'ENAME (type p1)))

(setq tx
                  (cons
                    (_text acspc
                      (_centroid acspc (list (setq p1 (vlax-ename->vla-object p1))))
                      (strcat pf (itoa (setq *al:num (1+ *al:num))) sf)
                      ts
                      ucsxang
                    )
                    tx
                  )
                )
                (vla-insertrows tb (setq n (1+ n)) th 1)
                (vla-settext tb n 1
                  (if fd
                    (strcat "%<\\AcObjProp Object(%<\\_ObjId "
                      (_GetObjectID acdoc p1) ">%).Area \\f \"" fo "\">%"
                    )
                    (strcat ap (rtos (* cf (vla-get-area p1)) 2) as)
                  )
                )
                (vla-settext tb n 0
                  (if fd
                    (strcat "%<\\AcObjProp Object(%<\\_ObjId "
                      (_GetObjectID acdoc (car tx)) ">%).TextString>%"
                    )
                    (strcat pf (itoa *al:num) sf)
                  )
                )
              )               
              ( (vl-consp p1)

(if el (progn (entdel el) (setq el nil)))
                (setq el (entlast))
                (vl-cmdf "_.-boundary" "_A" "_I" "_N" "" "_O" "_P" "" "_non" p1 "")

(if (not (equal el (setq el (entlast))))
                  (progn
                    (setq tx
                      (cons
                        (_text acspc
                          (_centroid acspc (list (vlax-ename->vla-object el)))
                          (strcat pf (itoa (setq *al:num (1+ *al:num))) sf)
                          ts
                          ucsxang
                        )
                        tx
                      )
                    )
                    (vla-insertrows tb (setq n (1+ n)) th 1)
                    (vla-settext tb n 1 (strcat ap (rtos (* cf (vlax-curve-getarea el)) 2) as))
                    (vla-settext tb n 0
                      (if fd
                        (strcat "%<\\AcObjProp Object(%<\\_ObjId "
                          (_GetObjectID acdoc (car tx)) ">%).TextString>%"
                        )
                        (strcat pf (itoa *al:num) sf)
                      )
                    )
                    (redraw el 3)
                  )
                  (princ "\n--> Error Retrieving Area.")
                )
              )
            )
          )
          (if el (progn (entdel el) (setq el nil)))
        )
      )
    )
    (
      (and
        (setq fl (getfiled "Create Output File" (cond ( *file* ) ( "" )) "txt;csv;xls" 1))
        (setq of (open fl "w"))
      )
      (setq *file*  (vl-filename-directory fl)
            de      (cdr (assoc (strcase (vl-filename-extension fl) t) '((".txt" . "\t") (".csv" . ",") (".xls" . "\t"))))
            *al:num (1- *al:num)
      )
      (write-line h1 of)
      (write-line (strcat t1 de t2) of)

(while
        (if om
          (setq p1
            (_Select (strcat "\nSelect Object [Pick] <Exit>: ")
             '(lambda ( x )
                (and
                  (vlax-property-available-p (vlax-ename->vla-object x) 'area)
                  (not (eq "HATCH" (cdr (assoc 0 (entget x)))))
                  (or (eq "REGION" (cdr (assoc 0 (entget x)))) (vlax-curve-isclosed x))
                )
              )
              entsel '("Pick")
            )
          )
          (progn (initget "Object") (setq p1 (getpoint (strcat "\nPick Area [Object] <Exit>: "))))
        )
        (cond
          ( (eq "Object" p1)

(if el (progn (entdel el) (setq el nil)))
            (setq om t)
          )
          ( (eq "Pick" p1)

(setq om nil)
          )
          ( (eq 'ENAME (type p1))

(_text acspc
              (_centroid acspc (list (setq p1 (vlax-ename->vla-object p1))))
              (strcat pf (itoa (setq *al:num (1+ *al:num))) sf)
              ts
              ucsxang
            )           
            (write-line (strcat pf (itoa *al:num) sf de ap (rtos (* cf (vla-get-area p1)) 2) as) of)
          )
          ( (vl-consp p1)
        
            (if el (progn (entdel el) (setq el nil)))
            (setq el (entlast))
            (vl-cmdf "_.-boundary" "_A" "_I" "_N" "" "_O" "_P" "" "_non" p1 "")

(if (not (equal el (setq el (entlast))))
              (progn
                (_text acspc
                  (_centroid acspc (list (vlax-ename->vla-object el)))
                  (strcat pf (itoa (setq *al:num (1+ *al:num))) sf)
                  ts
                  ucsxang
                )
                (write-line (strcat pf (itoa *al:num) sf de ap (rtos (* cf (vlax-curve-getarea el)) 2) as) of)
                (redraw el 3)
              )
              (princ "\n--> Error Retrieving Area.")
            )
          )
        )
      )
      (if el (progn (entdel el) (setq el nil)))
      (setq of (close of))
      (_Open (findfile fl))
    )      
  )
  (setenv "LMAC_AreaLabel" (if om "1" "0"))
  (setvar 'CMDECHO cm)
  (_EndUndo acdoc)
  (princ)
)

(vl-load-com)
(princ)
(princ "\n:: AreaLabel.lsp | Version 1.9 | © Lee Mac 2011 www.lee-mac.com ::")
(princ "\n:: Commands: \"AT\" for ACAD Table, \"AF\" for File ::")
(princ)

Autocad lisp çalıştırma

📜 Komut satırına "ALAN-TABLO" yazın ve enterlayın

📜Alan başlangıc numarası kaç olsun diye sorar.

Tıkladığınız her alan 1 2 3 4 5 diye ardişik olarak sıralanır.
İlk numara kaç olsun istiyorsanız onu yazın,
İstediğiniz sayıdan başlatabilirsiniz.
örnekte 1 yazıp enter tuşuna basıyorum

📜Pick point for table yazısı çıkacak.

tablonun nereye gelmesini istiyorsanız oraya tıklayın

📜Pick area yazacak.

Burada alanlara tıklayınız. Biraz dikkatli olmanız gerekir. çizginin üzerine değil alana tıklamanız gerekli
Şeklin alanına gittiğiniz zaman, şeklin ortasında yıldız işareti oluşur. tam oraya tıklayınız.

📜Tıklama sırasına göre alanlar numaralandırılır ve o numaralara göre alanlar tabloya yazılılır.

ilk karenin merkezine tıkladım kareye 1 denildi
Sonra üçgen merkezine tıkladım 2 yazıldı
Sonra dikdörtgen merkezine tıkladım 3 yazıldı
Sırası ile bu şekilde devam edildi.

alanları tabloya değilde başka bir dosyaya aktarmak için

📜 Komut satırına "ALAN-DOSYA" yazın ve enterlayın

📜Alanları ardışık olarak sıralanacak ilk sayıyı yazın

1 yazıp tıklıyorum

📜Dosyanın kaydedilecek yerini ve adını şeçin

Dosyayı excel (xls) olarak kaydedebilirsiniz
Dosyası not defteri (txt) olarak kaydedebilirsiniz
Dosya adını yazın
Nereye kadedeceğinizi seçin
Uzantısını seçin (excel veya not defteri)
Kaydet tıklayın

📜Şimdi yukarda olduğu gibi tek tek alanlara tıklayın ve enter tuşuna basın

Az önce olduğu gibi yine sırası ile kare, üçgen, dikdörtgen, çokgen, tıkladım
Enter tuşuna bastım
Kaydettiğiniz dosya açılacak

Autocad alanları numaralandırıp tabloya aktaran lisp daha fazla ara

👀 google

👀 yandex

👀 bing

👀 youtube

👀 facebook

👀 wikipedia

👀 google kitap

👀 google trends

👀 uzmantv

👀 twitter

👀 pinterest

👀 eksisozluk

Autocad alanları numaralandırıp tabloya aktaran lisp ilgili benzer konular

👀 autocad den excele tablo aktarma lisp

👀 autocad ölçülerini tabloya aktarma

👀 autocad mahal listesini excele aktarma

👀 autocad text to excel

👀 autocad lisp indir

👀 autocad excel bağlantısı

Autocad alanları numaralandırıp tabloya aktaran lisp - Metraj Lispi

Hiç yorum yok:
1 Mart 2021 Pazartesi

🐄 Metraj Lispi 🐅 Alan-Çevre Lispleri lisp

👱 Autocad de bulunan yazıları, excele satır halinde aktarmamızı sağlar,

👱 dtext ile yazılan yazıları aktarır

Autocad lisp kodlar

;      (princ "\t" dosya) OLARAK YAZILIRSA TAB'a basılmış gibi kaydeder....
;      Dosya sonra Excell de açılırken hüçrelere bölünmüş olarak açılır...
;      Yani Excell dosyası export edilmiş gibi olur.
(defun c:YAZI-EXCEL-SATIR ( / )
(command "layer" "new" "zyapimuhendisi.blogspot.com" "c" "3" "zyapimuhendisi.blogspot.com" "")
(setq donati_text (ssget '((0 . "TEXT")) ) )
(if (/= donati_text nil)
  (progn
    (setq donati_text_adet (sslength donati_text))
    (setq i 0 )
    (setq metraj_dosya (strcat (getvar "dwgprefix") (substr (getvar "dwgname") 1 (- (strlen (getvar "dwgname")) 4 )) "-YAZI-EXCEL-SATIR.xls"))
    (setq dosya (open metraj_dosya "a"))
   )
   (progn
    (princ "\n Dosyaya ara veriyoruz.......")
    (setq donati_text (ssget '((0 . "TEXT")) ) )
    (setq donati_text_adet (sslength donati_text))
    (setq i 0 )
    (setq dosya (open metraj_dosya "a"))
    (princ "\n " dosya)
    (princ "\n " dosya)
    (princ "\n " dosya)
    (princ "\n " dosya)
   )
)
   (while (< i donati_text_adet)
      (princ (cdr (assoc  1 (entget (ssname donati_text i))))  dosya)
      (setq d_eleman (entget (ssname donati_text i)))
      (setq old_feature (cdr (assoc 8 d_eleman)))
      (setq d_eleman (subst (cons 8 "zyapimuhendisi.blogspot.com") (assoc 8 d_eleman) d_eleman))
      (entmod d_eleman)
;*******************************************************************************
;                                                                              *
;     Bu satırın sonundaki t yi n yaparsanız tüm yazılar alt alta yazılır.     *
;                                                           "\t" -> "\n"       *
;*******************************************************************************
      (if (= i (- donati_text_adet 1))
        (princ "\n" dosya)
        (princ "\t" dosya)
      )
;*******************************************************************************
      (setq i (+ i 1))
   )
(close dosya)
(princ)
)

Autocad lisp çalıştırma

📜 Komut satırına "YAZI-EXCEL-SATIR" yazın ve enterlayın

📜İlk satıra yazılmasını istediğiniz yazıları seçin. örnekte yazı3 yazı4 yazı seçiyorum

📜Entera bas excele aktarılan yazılar yeşil renge döner

📜İkinci satıra yazılmasını istediğiniz yazıları için tekrar YAZI-EXCEL-SATIR yazın ve yazıları secin. örnekte yazı2 yazı7 yazı6 seçiyorum
Entera basıyorum. Bu yazılarda yeşile dönüşür. yani onlarda excele aktarıldı

📜 Şimdi yazıların aktarıldığı excel dosyasını bulalım.

Autocad dosyasının bulunduğu klasore gidin
AutoCAD ile aynı isimde sonunda YAZI-EXCEL-SATIR yayzan excel dosyasını bulun.
Ben autocad-lisp isimli autocad dosyasında çalışıyorum, ve aynı klasor içinde autocad-lisp-YAZI-EXCEL-SATIR yazan excel dosyasını buluyorum.
Excel dosyasına tıkla ve aç

📜Açılan dosyada ilk seçtiğim 3 yazı ilk satırda. Sonra tekrar komutu yazıp seçtiğim yazılar ise 2.satırda göreceksiniz.

AutoCAD da yazıları excele aktarma lispi (satıra aktar) - Metraj Lispi

Hiç yorum yok:
26 Şubat 2021 Cuma

🐃 Yazı Lispleri 🐄 Metraj Lispi lisp

👱 Autocad de seçilen yazıları excele aktarır. Seçtiğiniz herbir yazıyı excele sütuna yazar.

Autocad teki yazıları tek tek excele yazma veya kopyalayıp excele yazmaktan kurtulacaksınız.

Autocad lisp kodlar

;      (princ "\t" dosya) OLARAK YAZILIRSA TAB'a basılmış gibi kaydeder....
;      Dosya sonra Excell de açılırken hüçrelere bölünmüş olarak açılır...
;      Yani Excell dosyası export edilmiş gibi olur.
(defun c:YAZI-EXCEL-SUTUN ( / )
(command "layer" "new" "zyapimuhendisi.blogspot.com" "c" "3" "zyapimuhendisi.blogspot.com" "")
(setq donati_text (ssget '((0 . "TEXT")) ) )
(if (/= donati_text nil)
  (progn
    (setq donati_text_adet (sslength donati_text))
    (setq i 0 )
    (setq metraj_dosya (strcat (getvar "dwgprefix") (substr (getvar "dwgname") 1 (- (strlen (getvar "dwgname")) 4 )) "-YAZI-EXCEL-SUTUN.xls"))
    (setq dosya (open metraj_dosya "a"))
   )
   (progn
    (princ "\n Dosyaya ara veriyoruz.......")
    (setq donati_text (ssget '((0 . "TEXT")) ) )
    (setq donati_text_adet (sslength donati_text))
    (setq i 0 )
    (setq dosya (open metraj_dosya "a"))
    (princ "\n " dosya)
    (princ "\n " dosya)
    (princ "\n " dosya)
    (princ "\n " dosya)
   )
)
   (while (< i donati_text_adet)
      (princ (cdr (assoc  1 (entget (ssname donati_text i))))  dosya)
      (setq d_eleman (entget (ssname donati_text i)))
      (setq old_feature (cdr (assoc 8 d_eleman)))
      (setq d_eleman (subst (cons 8 "zyapimuhendisi.blogspot.com") (assoc 8 d_eleman) d_eleman))
      (entmod d_eleman)
;*******************************************************************************
;                                                                              *
;     Bu satırın sonundaki t yi n yaparsanız tüm yazılar alt alta yazılır.     *
;                                                           "\t" -> "\n"       *
;*******************************************************************************
      (if (= i (- donati_text_adet 1))
        (princ "\n" dosya)
        (princ "\n" dosya)
      )
;*******************************************************************************
      (setq i (+ i 1))
   )
(close dosya)
(princ)
)

Autocad lisp çalıştırma

📜 Komut satırına "YAZI-EXCEL-SUTUN" yazın ve enterlayın

📜 Excele aktarmak istediğiniz yazıları seçin. Sırası ile yazı3, yazı2, yazı1,yazı7 tıklıyorum.

📜Seçme işi bittikten sonra entera tıklayın. Entera bastıktan sonra yazılar yeşile dönüşecek, yeşil renge dönüşmüş yazılar. excele aktarıldı demektir.

📜Şimdi excel dosyasını bulalım

Önce autocad dosyanız hangi klasörde kayıtlı ise o klasörü açın
Autocad dosyanızla aynı isimde sonunda -YAZI-EXCEL-SUTUN yazan excel dosyasını bulun ve açın
Örnek olarak benim çalıştığım autocad dosyası autocad-lisp isimli dosya, aynı klasor içinde autocad-lisp-YAZI-EXCEL-SUTUN isinli dosyayı buluyorum ve açıyorum.

📜Excel dosyası açılınca tıkladığım butun yaziların a sutununda alt alta sıralandığını göreceksiniz.

AutoCAD da yazıları excele aktarma lispi (sutuna aktar) - Metraj Lispi

Hiç yorum yok:

🐃 Yazı Lispleri 🐄 Metraj Lispi lisp

👱 Bu lisp ile sadece seçilen yani sadece tıkladığım ölçüleri excele aktarır.

Autocad lisp kodlar

(defun c:OLCU-EXCEL-SECILEN (/ ss i sr d l xl n m)
  (if (setq ss (ssget '((0 . "dimension"))))
    (progn
      (repeat (setq i (sslength ss))
        (if (setq sr (vl-position (setq d (rtos (cdr (assoc 42 (entget
              (ssname ss (setq i (1- i)))))) 2 2)) (mapcar '(lambda(a) (car a)) l)))
          (setq l (subst (list (car (nth sr l)) (1+ (cadr (nth sr l)))) (nth sr l) l))
          (setq l (cons (list d 1) l))))
      (setq xl (open (getfiled "" "" "xls" 9) "w") n 0)
      (write-line (strcat "Sira No" "\t" "Dimension" "\t" "Miktar" "\t"
                    "Toplam Miktar") xl)
      (foreach m (vl-sort (mapcar '(lambda(a) (list (atof (car a)) (cadr a))) l)
                   '(lambda(a b) (< (car a) (car b))))
        (write-line (strcat (rtos (setq n (1+ n)) 2 0) "\t" (vl-string-translate "." ","
                      (rtos (car m) 2 2)) "\t" (rtos (cadr m) 2 0) "\t"
                      (strcat "=" "B" (itoa (1+ n)) "*" "C" (itoa (1+ n)))) xl))
      (write-line (strcat "\t" "Toplam" "\t"
                  (strcat "=" "TOPLA" "(" "C2" ":" "C" (itoa (1+ n)) ")") "\t"
                  (strcat "=" "TOPLA" "(" "D2" ":" "D" (itoa (1+ n)) ")")) xl)
      (close xl)
    )
  ) (princ)
)

AutoCAD lisp dosyasını kaydetme

Autocad lisp çalıştırma

Komut satırına "OLCU-EXCEL-SECILEN" yazın ve enterlayın.

Excele aktarmak istediğiniz ölçüleri tek tek secin, ve enter tuşuna basın

Örnekte önce 200
Sonra diğer 200
Sonra 400 tıklıyorum

Dosya yaratma penceresi açılacak.

Ölçülerin aktarılacağı excel dosyası nereye kayedileceğin ve ismini seçin
Kaydet tuşuna basın
Başka bir klasör ve başka bir isim yazmazsanız. çalıştığınız autocad klasörü içine ve autocad dosyası ile aynı isimde kayıt edilir.
örnekte autocad-lisp.xls olarak kayıt ediyorum

Şimdi autocad-lisp dosyasını bulup açıyorum.
3 adet ölçüye tıkladım. excele toplamda 3 ölçü aktarılmış
3 ölçünün genel toplamı verilir.

AutoCAD şeçilen ölçüleri excele aktarma lispi - Metraj Lispi

Hiç yorum yok:

🐄 Metraj Lispi 🐉 ölçü lisp lisp

Autocad lisp kodlar

AutoCAD iki nokta arasındaki uzunluğu yazan lisp resimli anlatım

AutoCAD iki nokta arasındaki uzunluğu yazan lisp daha fazla ara

AutoCAD iki nokta arasındaki uzunluğu yazan lisp ilgili benzer konular

Autocad lisp kodlar

Autocad lisp çalıştırma

Autocad lisp kodlar

Autocad lisp çalıştırma

📜Şimdi birden çok şeklin toplam alanını bulualım

AutoCAD toplam alanları satırda gösteren lisp daha fazla ara

AutoCAD toplam alanları satırda gösteren lisp ilgili benzer konular

Autocad lisp kodlar

Autocad lisp çalıştırma

alanları tabloya değilde başka bir dosyaya aktarmak için

Autocad alanları numaralandırıp tabloya aktaran lisp daha fazla ara

Autocad alanları numaralandırıp tabloya aktaran lisp ilgili benzer konular

Autocad lisp kodlar

Autocad lisp çalıştırma

Autocad lisp kodlar

Autocad lisp çalıştırma

Autocad lisp kodlar

AutoCAD lisp dosyasını kaydetme

Autocad lisp çalıştırma

Blog Arşivi